;ma.t1.pepz
;proton-detected T1 experiment 
;spin lock water suppression
;PEP-Z phase cycling scheme.
;
; hl1 = 6  dB (hard 1H)
; dl0 = 18 dB (15N decoupling)
;
; p1=1H  hard 90
; p2=1H  hard 180
; p3=15N hard 90
; p4=15N hard 180
; p15=0.5ms spinlock for H2O saturation
; p17=1.0ms spinlock for H2O saturation
; p31=15N soft 90 (decoupling during t2)
;
; d0=in0/2 - 2*p3/3.14 - p1
  d1=35m  ;for writing to buffer
; d2=1/4J (2.7m for 15N)
  d3=3u
; d4=(p3-p1)/2
; d5=de/2
; d6=aq
; d29=recycle delay
; in0=1/2*SW
;
; l0=number of t1 increments
; td1=2*l0 as we store 2 components separately
;
; T1 relaxation delay = l1*(2*d11+p2), set from au program.
;
  ze 
  d1 do
1 d1
  d1
  d1
  d1
  d1
  d1
2 d1 dhi hl1
  d29
  (p1 ph1)					;-Iy
  (d3 p17 ph17)
  d2
  (d4 d4 p2 ph2) (p4 ph3):d 
  d2						;2IxSz
  (d4 p1 ph2) (p3 ph3):d 
  d2						;2IzSy
  (d4 d4 p2 ph2) (p4 ph3):d 
  d2 
  (p3 ph4):d 					;-Sz
  (p15 ph15)
5 d11 
  (p2 ph3) 
  d11 				; T1 relax delay
  lo to 5 times l1
  (p15 ph15)
  (p3 ph5):d 				;Sy
  d0 				; t1
  (p2 ph13)
  d0
  d2 
  (d4 d4 p2 ph9) (p4 ph3):d 
  d2					;Sz coswt - 2IzSy sinwt
  (d4 p1 ph7) (p3 ph8):d 		;-Sy coswt + 2IySz sinwt
  d2
  (d4 d4 p2 ph9) (p4 ph6):d 
  d2					;2IzSx coswt - Ix sinwt
  (d4 p1 ph9) (p3 ph10):d 		;2IxSz coswt + Iz sinwt
  d2
  (d4 d4 p2 ph9) (p4 ph12):d 
  d2					;Iy coswt + Iz sinwt
  (p1 ph11)				;Iy coswt + Ix sinwt
  d5 dlo
  (d5 ph18)				
  d6 adc cpd
  (p16 ph15)
  d1 do
  rcyc=1 ph0
  d1 wr #0 if #0 zd
;
; second experiment
3 d1
  d1
  d1
  d1
  d1
  d1 dhi
  d29
  (p1 ph1)					;-Iy
  (d3 p17 ph17)
  d2
  (d4 d4 p2 ph2) (p4 ph3):d 
  d2						;2IxSz
  (d4 p1 ph2) (p3 ph3):d 
  d2						;2IzSy
  (d4 d4 p2 ph2) (p4 ph3):d 
  d2 
  (p3 ph4):d 
  (p15 ph15)
6 d11 
  (p2 ph3) 
  d11 				; T1 relax delay
  lo to 6 times l1
  (p15 ph15)
  (p3 ph5):d 
  d0 				; t1
  (p2 ph13)
  d0
  d2 
  (d4 d4 p2 ph9) (p4 ph3):d 
  d2
  (d4 p1 ph7) (p3 ph28):d 		;2IySz coswt + Sx sinwt
  d2
  (d4 d4 p2 ph9) (p4 ph26):d 
  d2
  (d4 p1 ph9) (p3 ph20):d 		;2IySz coswt + Sx sinwt
  d2
  (d4 d4 p2 ph9) (p4 ph22):d 
  d2
  (p1 ph11)
  d5 dlo
  (d5 ph18)				;-Ix coswt + Iy sinwt
  d6 adc cpd
  (p16 ph15)
  d1 do
  d1
  rcyc=3 ph0
  d1 wr #0 if #0 zd
  d1 ip0 id0
  d1 ip0
  d1 ip5
  d1 ip5
  lo to 2 times l0
exit
;

ph0= 0 2 2 0 2 0 0 2
;    2 0 0 2 0 2 2 0
ph1= 0 
ph2= 1
ph3= 0
ph4= 3
ph5= 0 2
ph6= 0 0 0 0 1 1 1 1
ph26=2 2 2 2 1 1 1 1
ph7= 1 1 1 1 0 0 0 0
ph8= 0 0 2 2 1 1 3 3
ph28=2 2 0 0 1 1 3 3
ph9= 0 0 0 0 3 3 3 3
ph10=1 1 3 3 2 2 0 0
ph20=1 1 3 3 0 0 2 2
ph11=3 3 3 3 2 2 2 2 
ph12=1 1 1 1 2 2 2 2
ph22=1 1 1 1 0 0 0 0
ph13=0 0 0 0 0 0 0 0
     2 2 2 2 2 2 2 2
ph15=0 
ph17=3
ph18=(360) 0	; to preset receiver phase